New Feature Request - rescan library from squeezetray

[antagron]

I don't know where to put this, so I'll put it here. I will repost to a Feature Request thread if someone directs me to one.

I would like Squeezetray to have an option for Rescan Library from the right click menu. Pretty simple!

[gharris999]

You can achieve the same thing yourself using a couple utilities, a windows batch file and a windows shortcut file.

Get the two utilities from here:

SCWOLTool.exe: http://code.google.com/p/srvrpowerct...l.exe&can=2&q=

SCCLITool.exe: http://code.google.com/p/srvrpowerct...t.exe&can=2&q=

Install the utilities and then create this batch file:

lms_wake_scan_for_new.cmd:

@echo off
set LMS_NAME=scserver
set LMS_MACADDR=aa:bb:cc:dd:ee:ff
set LMS_IP=192.168.1.123
set LMS_CLIPORT=9090
set BROADCASTIP=192.168.1.255
set NETMASK=255.255.255.0


:checkwake
echo Checking %LMS_NAME% status..
ping %LMS_IP% -n 1 -w 10 >NUL 2>&1

if errorlevel 1 goto wakeup
goto awake

:wakeup
echo %LMS_NAME% is asleep...attempting to wake it up..
rem Wakeup the server..
SCWOLTool.exe %LMS_MACADDR% %BROADCASTIP% %NETMASK% 7

sleep 18
goto checkwake

:awake

rem Rescan the whole library:
rem echo %LMS_NAME% is awake...initiating db wipe and rescan.
rem SCCLITool.exe wipecache -q -w 0 -h %LMS_IP% -p %LMS_CLIPORT%

rem Scan for new music:
echo %LMS_NAME% is awake...initiating scan for new music.
SCCLITool.exe rescan external -q -w 0 -h %LMS_IP% -p %LMS_CLIPORT%

You'll need to fix up the "set" values there with the correct IP and MAC address to match your setup. In the case where LMS is installed on your desktop computer, rather than a different server/machine, you can dispense with everything between :checkwake and :awake.

Put that batch file in C:\windows or wherever you'd like. Then create a shortcut to the batch file and drag the shortcut onto the windows 7 task bar.

Now, you can wake up your server and initiate a scan for new any time by just clicking the icon on the task bar.

PS: While your idea for this feature makes complete sense, there is no "feature request thread" here, per se. You can, however post feature requests to the LMS bug tracking system: http://bugs.slimdevices.com/